zig-bloxel-game/src/main.zig

const std = @import("std");
const core = @import("mach-core");
const gpu = core.gpu;

pub const App = @This();

title_timer: core.Timer,
pipeline: *gpu.RenderPipeline,

pub fn init(app: *App) !void {
    try core.init(.{});

    const shader_module = core.device.createShaderModuleWGSL("shader.wgsl", @embedFile("shader.wgsl"));
    defer shader_module.release();

    const blend = gpu.BlendState{};
    const color_target = gpu.ColorTargetState{
        .format = core.descriptor.format,
        .blend = &blend,
        .write_mask = gpu.ColorWriteMaskFlags.all,
    };
    const fragment = gpu.FragmentState.init(.{
        .module = shader_module,
        .entry_point = "frag_main",
        .targets = &.{color_target},
    });
    const pipeline_descriptor = gpu.RenderPipeline.Descriptor{
        .vertex = gpu.VertexState{
            .module = shader_module,
            .entry_point = "vertex_main",
        },
        .fragment = &fragment,
    };

    app.title_timer = try core.Timer.start();
    app.pipeline = core.device.createRenderPipeline(&pipeline_descriptor);
}

pub fn deinit(app: *App) void {
    defer core.deinit();
    defer app.pipeline.release();
}

pub fn update(app: *App) !bool {
    var iter = core.pollEvents();
    while (iter.next()) |event| {
        switch (event) {
            .close => return true,
            else => {},
        }
    }

    // Get back buffer texture to render to.
    const back_buffer_view = core.swap_chain.getCurrentTextureView().?;
    defer back_buffer_view.release();
    // Once rendering is done (hence `defer`), swap back buffer to the front to display.
    defer core.swap_chain.present();

    const color_attachment = gpu.RenderPassColorAttachment{
        .view = back_buffer_view,
        .clear_value = std.mem.zeroes(gpu.Color),
        .load_op = .clear,
        .store_op = .store,
    };
    const render_pass_info = gpu.RenderPassDescriptor.init(.{
        .color_attachments = &.{color_attachment},
    });

    // Create a `WGPUCommandEncoder` which provides an interface for recording GPU commands.
    const encoder = core.device.createCommandEncoder(null);
    defer encoder.release();

    {
        const pass = encoder.beginRenderPass(&render_pass_info);
        defer pass.release();
        defer pass.end();

        pass.setPipeline(app.pipeline);

        // Draw a triangle with the help of a specialized shader.
        pass.draw(3, 1, 0, 0);
    }

    // Finish recording commands, creating a `WGPUCommandBuffer`.
    var command = encoder.finish(null);
    defer command.release();

    // Submit the command(s) to the GPU.
    core.queue.submit(&.{command});

    // Update the window title to show FPS and input frequency.
    if (app.title_timer.read() >= 1.0) {
        app.title_timer.reset();
        try core.printTitle("Triangle [ {d}fps ] [ Input {d}hz ]", .{ core.frameRate(), core.inputRate() });
    }

    return false;
}